modules/Command.pm

   1 package Command;
   2
   3 #
   4 # Dev-Editor - Module Command
   5 #
   6 # Execute Dev-Editor's commands
   7 #
   8 # Author:        Patrick Canterino <patrick@patshaping.de>
   9 # Last modified: 2004-12-21
  10 #
  11
  12 use strict;
  13
  14 use vars qw(@EXPORT);
  15
  16 use File::Access;
  17 use File::Copy;
  18 use File::Path;
  19
  20 use POSIX qw(strftime);
  21 use Tool;
  22
  23 use CGI qw(header);
  24 use HTML::Entities;
  25 use Output;
  26 use Template;
  27
  28 my $script = encode_entities($ENV{'SCRIPT_NAME'});
  29 my $users  = eval("getpwuid(0)") && eval("getgrgid(0)");
  30
  31 my %dispatch = ('show'       => \&exec_show,
  32                 'beginedit'  => \&exec_beginedit,
  33                 'canceledit' => \&exec_canceledit,
  34                 'endedit'    => \&exec_endedit,
  35                 'mkdir'      => \&exec_mkdir,
  36                 'mkfile'     => \&exec_mkfile,
  37                 'upload'     => \&exec_upload,
  38                 'copy'       => \&exec_copy,
  39                 'rename'     => \&exec_rename,
  40                 'remove'     => \&exec_remove,
  41                 'chprop'     => \&exec_chprop,
  42                 'unlock'     => \&exec_unlock,
  43                 'about'      => \&exec_about
  44                );
  45
  46 ### Export ###
  47
  48 use base qw(Exporter);
  49
  50 @EXPORT = qw(exec_command);
  51
  52 # exec_command()
  53 #
  54 # Execute the specified command
  55 #
  56 # Params: 1. Command to execute
  57 #         2. Reference to user input hash
  58 #         3. Reference to config hash
  59 #
  60 # Return: Output of the command (Scalar Reference)
  61
  62 sub exec_command($$$)
  63 {
  64  my ($command,$data,$config) = @_;
  65
  66  foreach(keys(%dispatch))
  67  {
  68   if(lc($_) eq lc($command))
  69   {
  70    my $output = &{$dispatch{$_}}($data,$config);
  71    return $output;
  72   }
  73  }
  74
  75  return error($config->{'errors'}->{'cmd_unknown'},'/',{COMMAND => encode_entities($command)});
  76 }
  77
  78 # exec_show()
  79 #
  80 # View a directory or a file
  81 #
  82 # Params: 1. Reference to user input hash
  83 #         2. Reference to config hash
  84 #
  85 # Return: Output of the command (Scalar Reference)
  86
  87 sub exec_show($$)
  88 {
  89  my ($data,$config) = @_;
  90  my $physical       = $data->{'physical'};
  91  my $virtual        = $data->{'virtual'};
  92  my $upper_path     = encode_entities(upper_path($virtual));
  93  my $uselist        = $data->{'uselist'};
  94
  95  my $tpl = new Template;
  96
  97  if(-d $physical)
  98  {
  99   # Create directory listing
 100
 101   return error($config->{'errors'}->{'no_dir_access'},$upper_path) unless(-r $physical && -x $physical);
 102
 103   my $direntries = dir_read($physical);
 104   return error($config->{'dir_read_fail'},$upper_path,{DIR => encode_entities($virtual)}) unless($direntries);
 105
 106   my $files = $direntries->{'files'};
 107   my $dirs  = $direntries->{'dirs'};
 108
 109   my $dir_writeable = -w $physical;
 110
 111   my $dirlist = "";
 112
 113   # Create the link to the upper directory
 114   # (only if we are not in the root directory)
 115
 116   unless($virtual eq "/")
 117   {
 118    my @stat  = stat($physical."/..");
 119
 120    my $udtpl = new Template;
 121    $udtpl->read_file($config->{'templates'}->{'dirlist_up'});
 122
 123    $udtpl->fillin("UPPER_DIR",$upper_path);
 124    $udtpl->fillin("DATE",encode_entities(strftime($config->{'timeformat'},localtime($stat[9]))));
 125
 126    $dirlist .= $udtpl->get_template;
 127   }
 128
 129   # Directories
 130
 131   foreach my $dir(@$dirs)
 132   {
 133    my $phys_path = $physical."/".$dir;
 134    my $virt_path = encode_entities($virtual.$dir."/");
 135
 136    my @stat      = stat($phys_path);
 137
 138    my $dtpl = new Template;
 139    $dtpl->read_file($config->{'templates'}->{'dirlist_dir'});
 140
 141    $dtpl->fillin("DIR",$virt_path);
 142    $dtpl->fillin("DIR_NAME",encode_entities($dir));
 143    $dtpl->fillin("DATE",encode_entities(strftime($config->{'timeformat'},localtime($stat[9]))));
 144    $dtpl->fillin("URL",equal_url(encode_entities($config->{'httproot'}),$virt_path));
 145
 146    $dtpl->parse_if_block("readable",-r $phys_path && -x $phys_path);
 147    $dtpl->parse_if_block("users",$users && -o $phys_path);
 148
 149    $dirlist .= $dtpl->get_template;
 150   }
 151
 152   # Files
 153
 154   foreach my $file(@$files)
 155   {
 156    my $phys_path = $physical."/".$file;
 157    my $virt_path = encode_entities($virtual.$file);
 158
 159    my @stat      = stat($phys_path);
 160    my $in_use    = $uselist->in_use($virtual.$file);
 161    my $too_large = $config->{'max_file_size'} && $stat[7] > $config->{'max_file_size'};
 162
 163    my $ftpl = new Template;
 164    $ftpl->read_file($config->{'templates'}->{'dirlist_file'});
 165
 166    $ftpl->fillin("FILE",$virt_path);
 167    $ftpl->fillin("FILE_NAME",encode_entities($file));
 168    $ftpl->fillin("SIZE",$stat[7]);
 169    $ftpl->fillin("DATE",encode_entities(strftime($config->{'timeformat'},localtime($stat[9]))));
 170    $ftpl->fillin("URL",equal_url(encode_entities($config->{'httproot'}),$virt_path));
 171
 172    $ftpl->parse_if_block("not_readable",not -r $phys_path);
 173    $ftpl->parse_if_block("binary",-B $phys_path);
 174    $ftpl->parse_if_block("readonly",not -w $phys_path);
 175
 176    $ftpl->parse_if_block("viewable",-r $phys_path && -T $phys_path && not $too_large);
 177    $ftpl->parse_if_block("editable",(-r $phys_path && -w $phys_path && -T $phys_path && not $too_large) && not $in_use);
 178
 179    $ftpl->parse_if_block("in_use",$in_use);
 180    $ftpl->parse_if_block("unused",not $in_use);
 181
 182    $ftpl->parse_if_block("too_large",$config->{'max_file_size'} && $stat[7] > $config->{'max_file_size'});
 183
 184    $ftpl->parse_if_block("users",$users && -o $phys_path);
 185
 186    $dirlist .= $ftpl->get_template;
 187   }
 188
 189   $tpl->read_file($config->{'templates'}->{'dirlist'});
 190
 191   $tpl->fillin("DIRLIST",$dirlist);
 192   $tpl->fillin("DIR",encode_entities($virtual));
 193   $tpl->fillin("SCRIPT",$script);
 194   $tpl->fillin("URL",encode_entities(equal_url($config->{'httproot'},$virtual)));
 195
 196   $tpl->parse_if_block("dir_writeable",$dir_writeable);
 197  }
 198  else
 199  {
 200   # View a file
 201
 202   return error($config->{'errors'}->{'no_view'},$upper_path) unless(-r $physical);
 203
 204   # Check on binary files
 205   # We have to do it in this way, or empty files
 206   # will be recognized as binary files
 207
 208   unless(-T $physical)
 209   {
 210    # Binary file
 211
 212    return error($config->{'errors'}->{'binary'},$upper_path);
 213   }
 214   else
 215   {
 216    # Text file
 217
 218    if($config->{'max_file_size'} && -s $physical > $config->{'max_file_size'})
 219    {
 220     return error($config->{'errors'}->{'file_too_large'},$upper_path,{SIZE => $config->{'max_file_size'}})
 221    }
 222    else
 223    {
 224     my $content =  file_read($physical);
 225     $$content   =~ s/\015\012|\012|\015/\n/g;
 226
 227     $tpl->read_file($config->{'templates'}->{'viewfile'});
 228
 229     $tpl->fillin("FILE",encode_entities($virtual));
 230     $tpl->fillin("DIR",$upper_path);
 231     $tpl->fillin("URL",encode_entities(equal_url($config->{'httproot'},$virtual)));
 232     $tpl->fillin("SCRIPT",$script);
 233
 234     $tpl->parse_if_block("editable",-w $physical && $uselist->unused($virtual));
 235
 236     $tpl->fillin("CONTENT",encode_entities($$content));
 237    }
 238   }
 239  }
 240
 241  my $output  = header(-type => "text/html");
 242  $output    .= $tpl->get_template;
 243
 244  return \$output;
 245 }
 246
 247 # exec_beginedit
 248 #
 249 # Lock a file and display a form to edit it
 250 #
 251 # Params: 1. Reference to user input hash
 252 #         2. Reference to config hash
 253 #
 254 # Return: Output of the command (Scalar Reference)
 255
 256 sub exec_beginedit($$)
 257 {
 258  my ($data,$config) = @_;
 259  my $physical       = $data->{'physical'};
 260  my $virtual        = $data->{'virtual'};
 261  my $dir            = upper_path($virtual);
 262  my $uselist        = $data->{'uselist'};
 263
 264  return error($config->{'errors'}->{'editdir'},$dir)                    if(-d $physical);
 265  return error($config->{'errors'}->{'in_use'}, $dir,{FILE => $virtual}) if($uselist->in_use($virtual));
 266  return error($config->{'errors'}->{'no_edit'},$dir)                    unless(-r $physical && -w $physical);
 267
 268  # Check on binary files
 269
 270  unless(-T $physical)
 271  {
 272   # Binary file
 273
 274   return error($config->{'errors'}->{'binary'},$dir);
 275  }
 276  else
 277  {
 278   if($config->{'max_file_size'} && -s $physical > $config->{'max_file_size'})
 279   {
 280    return error($config->{'errors'}->{'file_too_large'},$dir,{SIZE => $config->{'max_file_size'}})
 281   }
 282   else
 283   {
 284    # Text file
 285
 286    $uselist->add_file($virtual);
 287    $uselist->save;
 288
 289    my $content =  file_read($physical);
 290    $$content   =~ s/\015\012|\012|\015/\n/g;
 291
 292    my $tpl = new Template;
 293    $tpl->read_file($config->{'templates'}->{'editfile'});
 294
 295    $tpl->fillin("FILE",$virtual);
 296    $tpl->fillin("DIR",$dir);
 297    $tpl->fillin("URL",equal_url($config->{'httproot'},$virtual));
 298    $tpl->fillin("SCRIPT",$script);
 299    $tpl->fillin("CONTENT",encode_entities($$content));
 300
 301    my $output = header(-type => "text/html");
 302    $output   .= $tpl->get_template;
 303
 304    return \$output;
 305   }
 306  }
 307 }
 308
 309 # exec_canceledit()
 310 #
 311 # Abort file editing
 312 #
 313 # Params: 1. Reference to user input hash
 314 #         2. Reference to config hash
 315 #
 316 # Return: Output of the command (Scalar Reference)
 317
 318 sub exec_canceledit($$)
 319 {
 320  my ($data,$config) = @_;
 321  my $virtual        = $data->{'virtual'};
 322
 323  file_unlock($data->{'uselist'},$virtual);
 324  return devedit_reload({command => 'show', file => upper_path($virtual)});
 325 }
 326
 327 # exec_endedit()
 328 #
 329 # Save a file, unlock it and return to directory view
 330 #
 331 # Params: 1. Reference to user input hash
 332 #         2. Reference to config hash
 333 #
 334 # Return: Output of the command (Scalar Reference)
 335
 336 sub exec_endedit($$)
 337 {
 338  my ($data,$config) = @_;
 339  my $physical       = $data->{'physical'};
 340  my $virtual        = $data->{'virtual'};
 341  my $dir            = upper_path($virtual);
 342  my $content        = $data->{'cgi'}->param('filecontent');
 343  my $uselist        = $data->{'uselist'};
 344
 345  # We already unlock the file at the beginning of the subroutine,
 346  # because if we have to abort this routine, the file keeps locked.
 347  # No other user of Dev-Editor will access the file during this
 348  # routine because of the concept of File::UseList.
 349
 350  file_unlock($uselist,$virtual);
 351
 352  # Normalize newlines
 353
 354  $content =~ s/\015\012|\012|\015/\n/g;
 355
 356  if($data->{'cgi'}->param('encode_iso'))
 357  {
 358   # Encode all ISO-8859-1 special chars
 359
 360   $content = encode_entities($content,"\200-\377");
 361  }
 362
 363  if($data->{'cgi'}->param('saveas') && $data->{'new_physical'} ne '' && $data->{'new_virtual'} ne '')
 364  {
 365   # Create the new filename
 366
 367   $physical = $data->{'new_physical'};
 368   $virtual  = $data->{'new_virtual'};
 369
 370   # Check if someone else is editing the new file
 371
 372   return error($config->{'errors'}->{'in_use'},$dir,{FILE => $virtual}) if($uselist->in_use($virtual));
 373  }
 374
 375  return error($config->{'errors'}->{'editdir'},$dir)        if(-d $physical);
 376  return error($config->{'errors'}->{'no_edit'},$dir)        if(-e $physical && !(-r $physical && -w $physical));
 377  return error($config->{'errors'}->{'text_to_binary'},$dir) unless(-T $physical);
 378
 379  if(file_save($physical,\$content))
 380  {
 381   # Saving of the file was successful!
 382
 383   return devedit_reload({command => 'show', file => $dir});
 384  }
 385  else
 386  {
 387   return error($config->{'errors'}->{'edit_failed'},$dir,{FILE => $virtual});
 388  }
 389 }
 390
 391 # exec_mkfile()
 392 #
 393 # Create a file and return to directory view
 394 #
 395 # Params: 1. Reference to user input hash
 396 #         2. Reference to config hash
 397 #
 398 # Return: Output of the command (Scalar Reference)
 399
 400 sub exec_mkfile($$)
 401 {
 402  my ($data,$config) = @_;
 403  my $new_physical   = $data->{'new_physical'};
 404  my $new_virtual    = $data->{'new_virtual'};
 405  my $dir            = upper_path($new_virtual);
 406  $new_virtual       = encode_entities($new_virtual);
 407
 408  if($new_physical)
 409  {
 410   return error($config->{'errors'}->{'file_exists'},$dir,{FILE => $new_virtual}) if(-e $new_physical);
 411
 412   file_create($new_physical) or return error($config->{'errors'}->{'mkfile_failed'},$dir,{FILE => $new_virtual});
 413   return devedit_reload({command => 'show', file => $dir});
 414  }
 415  else
 416  {
 417   my $tpl = new Template;
 418   $tpl->read_file($config->{'templates'}->{'mkfile'});
 419
 420   $tpl->fillin("DIR","/");
 421   $tpl->fillin("SCRIPT",$script);
 422
 423   my $output = header(-type => "text/html");
 424   $output   .= $tpl->get_template;
 425
 426   return \$output;
 427  }
 428 }
 429
 430 # exec_mkdir()
 431 #
 432 # Create a directory and return to directory view
 433 #
 434 # Params: 1. Reference to user input hash
 435 #         2. Reference to config hash
 436 #
 437 # Return: Output of the command (Scalar Reference)
 438
 439 sub exec_mkdir($$)
 440 {
 441  my ($data,$config) = @_;
 442  my $new_physical   = $data->{'new_physical'};
 443  my $new_virtual    = $data->{'new_virtual'};
 444  my $dir            = upper_path($new_virtual);
 445  $new_virtual       = encode_entities($new_virtual);
 446
 447  return error($config->{'errors'}->{'file_exists'},$dir,{FILE => $new_virtual}) if(-e $new_physical);
 448
 449  if($new_physical)
 450  {
 451   mkdir($new_physical,0777) or return error($config->{'errors'}->{'mkdir_failed'},$dir,{DIR => $new_virtual});
 452   return devedit_reload({command => 'show', file => $dir});
 453  }
 454  else
 455  {
 456   my $tpl = new Template;
 457   $tpl->read_file($config->{'templates'}->{'mkdir'});
 458
 459   $tpl->fillin("DIR","/");
 460   $tpl->fillin("SCRIPT",$script);
 461
 462   my $output = header(-type => "text/html");
 463   $output   .= $tpl->get_template;
 464
 465   return \$output;
 466  }
 467 }
 468
 469 # exec_upload()
 470 #
 471 # Upload a file
 472 #
 473 # Params: 1. Reference to user input hash
 474 #         2. Reference to config hash
 475 #
 476 # Return: Output of the command (Scalar Reference)
 477
 478 sub exec_upload($$)
 479 {
 480  my ($data,$config) = @_;
 481  my $physical       = $data->{'physical'};
 482  my $virtual        = $data->{'virtual'};
 483  my $cgi            = $data->{'cgi'};
 484
 485  return error($config->{'errors'}->{'no_directory'},upper_path($virtual),{FILE => $virtual}) unless(-d $physical);
 486  return error($config->{'errors'}->{'dir_no_create'},$virtual,{DIR => $virtual})             unless(-w $physical);
 487
 488  if(my $uploaded_file = $cgi->param('uploaded_file'))
 489  {
 490   # Process file upload
 491
 492   my $filename  = file_name($uploaded_file);
 493   my $file_phys = $physical."/".$filename;
 494   my $file_virt = $virtual.$filename;
 495
 496   return error($config->{'errors'}->{'in_use'},$virtual,{FILE => $file_virt}) if($data->{'uselist'}->in_use($file_virt));
 497
 498   if(-e $file_phys)
 499   {
 500    return error($config->{'errors'}->{'dir_replace'},$virtual)                         if(-d $file_phys);
 501    return error($config->{'errors'}->{'exist_no_write'},$virtual,{FILE => $file_virt}) unless(-w $file_phys);
 502    return error($config->{'errors'}->{'file_exists'},$virtual,{FILE => $file_virt})    unless($cgi->param('overwrite'));
 503   }
 504
 505   my $ascii     = $cgi->param('ascii');
 506   my $handle    = $cgi->upload('uploaded_file');
 507
 508   # Read transferred file and write it to disk
 509
 510   read($handle, my $data, -s $handle);
 511   $data =~ s/\015\012|\012|\015/\n/g if($ascii); # Replace line separators if transferring in ASCII mode
 512   file_save($file_phys,\$data,not $ascii) or return error($config->{'errors'}->{'mkfile_failed'},$virtual,{FILE => $file_virt});
 513
 514   return devedit_reload({command => "show", file => $virtual});
 515  }
 516  else
 517  {
 518   my $tpl = new Template;
 519   $tpl->read_file($config->{'templates'}->{'upload'});
 520
 521   $tpl->fillin("DIR",$virtual);
 522   $tpl->fillin("URL",equal_url($config->{'httproot'},$virtual));
 523   $tpl->fillin("SCRIPT",$script);
 524
 525   my $output = header(-type => "text/html");
 526   $output   .= $tpl->get_template;
 527
 528   return \$output;
 529  }
 530 }
 531
 532 # exec_copy()
 533 #
 534 # Copy a file and return to directory view
 535 #
 536 # Params: 1. Reference to user input hash
 537 #         2. Reference to config hash
 538 #
 539 # Return: Output of the command (Scalar Reference)
 540
 541 sub exec_copy($$)
 542 {
 543  my ($data,$config) = @_;
 544  my $physical       = $data->{'physical'};
 545  my $virtual        = encode_entities($data->{'virtual'});
 546  my $dir            = upper_path($virtual);
 547  my $new_physical   = $data->{'new_physical'};
 548
 549  return error($config->{'errors'}->{'dircopy'},$dir) if(-d $physical);
 550  return error($config->{'errors'}->{'no_copy'},$dir) unless(-r $physical);
 551
 552  if($new_physical)
 553  {
 554   my $new_virtual = $data->{'new_virtual'};
 555   my $new_dir     = upper_path($new_virtual);
 556   $new_virtual    = encode_entities($new_virtual);
 557
 558   if(-e $new_physical)
 559   {
 560    return error($config->{'errors'}->{'exist_edited'},$new_dir,{FILE => $new_virtual})   if($data->{'uselist'}->in_use($data->{'new_virtual'}));
 561    return error($config->{'errors'}->{'dir_replace'},$new_dir)                           if(-d $new_physical);
 562    return error($config->{'errors'}->{'exist_no_write'},$new_dir,{FILE => $new_virtual}) unless(-w $new_physical);
 563
 564    if(not $data->{'cgi'}->param('confirmed'))
 565    {
 566     my $tpl = new Template;
 567     $tpl->read_file($config->{'templates'}->{'confirm_replace'});
 568
 569     $tpl->fillin("FILE",$virtual);
 570     $tpl->fillin("NEW_FILE",$new_virtual);
 571     $tpl->fillin("NEW_FILENAME",file_name($new_virtual));
 572     $tpl->fillin("NEW_DIR",$new_dir);
 573     $tpl->fillin("DIR",$dir);
 574
 575     $tpl->fillin("COMMAND","copy");
 576     $tpl->fillin("URL",equal_url($config->{'httproot'},$virtual));
 577     $tpl->fillin("SCRIPT",$script);
 578
 579     my $output = header(-type => "text/html");
 580     $output   .= $tpl->get_template;
 581
 582     return \$output;
 583    }
 584   }
 585
 586   copy($physical,$new_physical) or return error($config->{'errors'}->{'copy_failed'},$dir,{FILE => $virtual, NEW_FILE => $new_virtual});
 587   return devedit_reload({command => 'show', file => $new_dir});
 588  }
 589  else
 590  {
 591   my $tpl = new Template;
 592   $tpl->read_file($config->{'templates'}->{'copyfile'});
 593
 594   $tpl->fillin("FILE",$virtual);
 595   $tpl->fillin("DIR",$dir);
 596   $tpl->fillin("URL",equal_url($config->{'httproot'},$virtual));
 597   $tpl->fillin("SCRIPT",$script);
 598
 599   my $output = header(-type => "text/html");
 600   $output   .= $tpl->get_template;
 601
 602   return \$output;
 603  }
 604 }
 605
 606 # exec_rename()
 607 #
 608 # Rename/move a file and return to directory view
 609 #
 610 # Params: 1. Reference to user input hash
 611 #         2. Reference to config hash
 612 #
 613 # Return: Output of the command (Scalar Reference)
 614
 615 sub exec_rename($$)
 616 {
 617  my ($data,$config) = @_;
 618  my $physical       = $data->{'physical'};
 619  my $virtual        = $data->{'virtual'};
 620  my $dir            = upper_path($virtual);
 621  my $new_physical   = $data->{'new_physical'};
 622
 623  return error($config->{'errors'}->{'rename_root'},"/")                if($virtual eq "/");
 624  return error($config->{'errors'}->{'no_rename'},$dir)                 unless(-w upper_path($physical));
 625  return error($config->{'errors'}->{'in_use'},$dir,{FILE => $virtual}) if($data->{'uselist'}->in_use($virtual));
 626
 627  if($new_physical)
 628  {
 629   my $new_virtual = $data->{'new_virtual'};
 630   my $new_dir     = upper_path($new_virtual);
 631   $new_virtual    = encode_entities($new_virtual);
 632
 633   if(-e $new_physical)
 634   {
 635    return error($config->{'errors'}->{'exist_edited'},$new_dir,{FILE => $new_virtual})   if($data->{'uselist'}->in_use($data->{'new_virtual'}));
 636    return error($config->{'errors'}->{'dir_replace'},$new_dir)                           if(-d $new_physical);
 637    return error($config->{'errors'}->{'exist_no_write'},$new_dir,{FILE => $new_virtual}) unless(-w $new_physical);
 638
 639    if(not $data->{'cgi'}->param('confirmed'))
 640    {
 641     my $tpl = new Template;
 642     $tpl->read_file($config->{'templates'}->{'confirm_replace'});
 643
 644     $tpl->fillin("FILE",$virtual);
 645     $tpl->fillin("NEW_FILE",$new_virtual);
 646     $tpl->fillin("NEW_FILENAME",file_name($new_virtual));
 647     $tpl->fillin("NEW_DIR",$new_dir);
 648     $tpl->fillin("DIR",$dir);
 649
 650     $tpl->fillin("COMMAND","rename");
 651     $tpl->fillin("URL",equal_url($config->{'httproot'},$virtual));
 652     $tpl->fillin("SCRIPT",$script);
 653
 654     my $output = header(-type => "text/html");
 655     $output   .= $tpl->get_template;
 656
 657     return \$output;
 658    }
 659   }
 660
 661   rename($physical,$new_physical) or return error($config->{'errors'}->{'rename_failed'},$dir,{FILE => $virtual, NEW_FILE => $new_virtual});
 662   return devedit_reload({command => 'show', file => $new_dir});
 663  }
 664  else
 665  {
 666   my $tpl = new Template;
 667   $tpl->read_file($config->{'templates'}->{'renamefile'});
 668
 669   $tpl->fillin("FILE",$virtual);
 670   $tpl->fillin("DIR",$dir);
 671   $tpl->fillin("URL",equal_url($config->{'httproot'},$virtual));
 672   $tpl->fillin("SCRIPT",$script);
 673
 674   my $output = header(-type => "text/html");
 675   $output   .= $tpl->get_template;
 676
 677   return \$output;
 678  }
 679 }
 680
 681 # exec_remove()
 682 #
 683 # Remove a file or a directory and return to directory view
 684 #
 685 # Params: 1. Reference to user input hash
 686 #         2. Reference to config hash
 687 #
 688 # Return: Output of the command (Scalar Reference)
 689
 690 sub exec_remove($$)
 691 {
 692  my ($data,$config) = @_;
 693  my $physical       = $data->{'physical'};
 694  my $virtual        = $data->{'virtual'};
 695  my $dir            = upper_path($virtual);
 696
 697  return error($config->{'errors'}->{'remove_root'},"/") if($virtual eq "/");
 698  return error($config->{'errors'}->{'no_delete'},$dir)  unless(-w upper_path($physical));
 699
 700  if(-d $physical)
 701  {
 702   # Remove a directory
 703
 704   if($data->{'cgi'}->param('confirmed'))
 705   {
 706    rmtree($physical);
 707    return devedit_reload({command => 'show', file => $dir});
 708   }
 709   else
 710   {
 711    my $tpl = new Template;
 712    $tpl->read_file($config->{'templates'}->{'confirm_rmdir'});
 713
 714    $tpl->fillin("DIR",$virtual);
 715    $tpl->fillin("UPPER_DIR",$dir);
 716    $tpl->fillin("URL",equal_url($config->{'httproot'},$virtual));
 717    $tpl->fillin("SCRIPT",$script);
 718
 719    my $output = header(-type => "text/html");
 720    $output   .= $tpl->get_template;
 721
 722    return \$output;
 723   }
 724  }
 725  else
 726  {
 727   # Remove a file
 728
 729   return error($config->{'errors'}->{'in_use'},$dir,{FILE => $virtual}) if($data->{'uselist'}->in_use($virtual));
 730
 731   if($data->{'cgi'}->param('confirmed'))
 732   {
 733    unlink($physical) or return error($config->{'errors'}->{'delete_failed'},$dir,{FILE => $virtual});
 734    return devedit_reload({command => 'show', file => $dir});
 735   }
 736   else
 737   {
 738    my $tpl = new Template;
 739    $tpl->read_file($config->{'templates'}->{'confirm_rmfile'});
 740
 741    $tpl->fillin("FILE",$virtual);
 742    $tpl->fillin("DIR",$dir);
 743    $tpl->fillin("URL",equal_url($config->{'httproot'},$virtual));
 744    $tpl->fillin("SCRIPT",$script);
 745
 746    my $output = header(-type => "text/html");
 747    $output   .= $tpl->get_template;
 748
 749    return \$output;
 750   }
 751  }
 752 }
 753
 754 # exec_chprop()
 755 #
 756 # Change the mode and the group of a file or a directory
 757 #
 758 # Params: 1. Reference to user input hash
 759 #         2. Reference to config hash
 760 #
 761 # Return: Output of the command (Scalar Reference)
 762
 763 sub exec_chprop($$)
 764 {
 765  my ($data,$config) = @_;
 766  my $physical       = $data->{'physical'};
 767  my $virtual        = $data->{'virtual'};
 768  my $dir            = upper_path($virtual);
 769
 770  return error($config->{'errors'}->{'no_users'},$dir,{FILE => $virtual})  unless($users);
 771  return error($config->{'errors'}->{'chprop_root'},"/")                   if($virtual eq "/");
 772  return error($config->{'errors'}->{'not_owner'},$dir,{FILE => $virtual}) unless(-o $physical);
 773  return error($config->{'errors'}->{'in_use'},$dir,{FILE => $virtual})    if($data->{'uselist'}->in_use($virtual));
 774
 775  my $cgi   = $data->{'cgi'};
 776  my $mode  = $cgi->param('mode');
 777  my $group = $cgi->param('group');
 778
 779  if($mode || $group)
 780  {
 781   if($mode)
 782   {
 783    # Change the mode
 784
 785    chmod(oct($mode),$physical);
 786   }
 787
 788   if($group)
 789   {
 790    # Change the group using the `chgrp` system command
 791
 792    return error($config->{'errors'}->{'invalid_group'},$dir,{GROUP => encode_entities($group)}) unless($group =~ /^[a-z0-9_]+[a-z0-9_-]*$/i);
 793    system("chgrp",$group,$physical);
 794   }
 795
 796   return devedit_reload({command => 'show', file => $dir});
 797  }
 798  else
 799  {
 800   # Display the form
 801
 802   my @stat = stat($physical);
 803   my $mode = $stat[2];
 804   my $gid  = $stat[5];
 805
 806   my $tpl = new Template;
 807   $tpl->read_file($config->{'templates'}->{'chprop'});
 808
 809   # Insert file properties into the template
 810
 811   $tpl->fillin("MODE_OCTAL",substr(sprintf("%04o",$mode),-4));
 812   $tpl->fillin("MODE_STRING",mode_string($mode));
 813   $tpl->fillin("GID",$gid);
 814
 815   if(my $group = getgrgid($gid))
 816   {
 817    $tpl->fillin("GROUP",encode_entities($group));
 818    $tpl->parse_if_block("group_detected",1);
 819   }
 820   else
 821   {
 822    $tpl->parse_if_block("group_detected",0);
 823   }
 824
 825   # Insert other information
 826
 827   $tpl->fillin("FILE",$virtual);
 828   $tpl->fillin("DIR",$dir);
 829   $tpl->fillin("URL",equal_url($config->{'httproot'},$virtual));
 830   $tpl->fillin("SCRIPT",$script);
 831
 832   my $output = header(-type => "text/html");
 833   $output   .= $tpl->get_template;
 834
 835   return \$output;
 836  }
 837 }
 838
 839 # exec_unlock()
 840 #
 841 # Remove a file from the list of used files and
 842 # return to directory view
 843 #
 844 # Params: 1. Reference to user input hash
 845 #         2. Reference to config hash
 846 #
 847 # Return: Output of the command (Scalar Reference)
 848
 849 sub exec_unlock($$)
 850 {
 851  my ($data,$config) = @_;
 852  my $virtual        = $data->{'virtual'};
 853  my $uselist        = $data->{'uselist'};
 854  my $dir            = upper_path($virtual);
 855
 856  return devedit_reload({command => 'show', file => $dir}) if($uselist->unused($virtual));
 857
 858  if($data->{'cgi'}->param('confirmed'))
 859  {
 860   file_unlock($uselist,$virtual);
 861   return devedit_reload({command => 'show', file => $dir});
 862  }
 863  else
 864  {
 865   my $tpl = new Template;
 866   $tpl->read_file($config->{'templates'}->{'confirm_unlock'});
 867
 868   $tpl->fillin("FILE",$virtual);
 869   $tpl->fillin("DIR",$dir);
 870   $tpl->fillin("URL",equal_url($config->{'httproot'},$virtual));
 871   $tpl->fillin("SCRIPT",$script);
 872
 873   my $output = header(-type => "text/html");
 874   $output   .= $tpl->get_template;
 875
 876   return \$output;
 877  }
 878 }
 879
 880 # exec_about()
 881 #
 882 # Display some information about Dev-Editor
 883 #
 884 # Params: 1. Reference to user input hash
 885 #         2. Reference to config hash
 886 #
 887 # Return: Output of the command (Scalar Reference)
 888
 889 sub exec_about($$)
 890 {
 891  my ($data,$config) = @_;
 892
 893  my $tpl = new Template;
 894  $tpl->read_file($config->{'templates'}->{'about'});
 895
 896  $tpl->fillin("SCRIPT",$script);
 897
 898  # Dev-Editor's version number
 899
 900  $tpl->fillin("VERSION",$data->{'version'});
 901
 902  # Some path information
 903
 904  $tpl->fillin("SCRIPT_PHYS",encode_entities($ENV{'SCRIPT_FILENAME'}));
 905  $tpl->fillin("CONFIG_PATH",encode_entities($data->{'configfile'}));
 906  $tpl->fillin("FILE_ROOT",  encode_entities($config->{'fileroot'}));
 907  $tpl->fillin("HTTP_ROOT",  encode_entities($config->{'httproot'}));
 908
 909  # Perl
 910
 911  $tpl->fillin("PERL_PROG",encode_entities($^X));
 912  $tpl->fillin("PERL_VER", sprintf("%vd",$^V));
 913
 914  # Information about the server
 915
 916  $tpl->fillin("HTTPD",encode_entities($ENV{'SERVER_SOFTWARE'}));
 917  $tpl->fillin("OS",   encode_entities($^O));
 918  $tpl->fillin("TIME", encode_entities(strftime($config->{'timeformat'},localtime)));
 919
 920  # Process information
 921
 922  $tpl->fillin("PID",$$);
 923
 924  # Check if the functions getpwuid() and getgrgid() are available
 925
 926  if($users)
 927  {
 928   # Dev-Editor is running on a system which allows users and groups
 929   # So we display the user and the group of our process
 930
 931   my $uid = POSIX::getuid;
 932   my $gid = POSIX::getgid;
 933
 934   $tpl->parse_if_block("users",1);
 935
 936   # ID's of user and group
 937
 938   $tpl->fillin("UID",$uid);
 939   $tpl->fillin("GID",$gid);
 940
 941   # Names of user and group
 942
 943   if(my $user = getpwuid($uid))
 944   {
 945    $tpl->fillin("USER",encode_entities($user));
 946    $tpl->parse_if_block("user_detected",1);
 947   }
 948   else
 949   {
 950    $tpl->parse_if_block("user_detected",0);
 951   }
 952
 953   if(my $group = getgrgid($gid))
 954   {
 955    $tpl->fillin("GROUP",encode_entities($group));
 956    $tpl->parse_if_block("group_detected",1);
 957   }
 958   else
 959   {
 960    $tpl->parse_if_block("group_detected",0);
 961   }
 962
 963   # Process umask
 964
 965   $tpl->fillin("UMASK",sprintf("%04o",umask));
 966  }
 967  else
 968  {
 969   $tpl->parse_if_block("users",0);
 970  }
 971
 972  my $output = header(-type => "text/html");
 973  $output   .= $tpl->get_template;
 974
 975  return \$output;
 976 }
 977
 978 # it's true, baby ;-)
 979
 980 1;
 981
 982 #
 983 ### End ###