devedit.pl

   1 #!C:/Programme/Perl/bin/perl.exe -w
   2
   3 #
   4 # Dev-Editor 3.0.1
   5 #
   6 # Dev-Editor's main program
   7 #
   8 # Author:        Patrick Canterino <patrick@patshaping.de>
   9 # Last modified: 2006-08-24
  10 #
  11
  12 use strict;
  13 use CGI::Carp qw(fatalsToBrowser);
  14
  15 use vars qw($VERSION);
  16 use lib 'modules';
  17
  18 use CGI;
  19 use Config::DevEdit;
  20
  21 use Command;
  22 use Output;
  23 use Tool;
  24
  25 $VERSION = '3.0.1';
  26
  27 # Path to configuration file
  28 # Change if necessary!
  29
  30 use constant CONFIGFILE => 'devedit.conf';
  31
  32 # Read the configuration file
  33
  34 my $config = read_config(CONFIGFILE);
  35 error_template($config->{'templates'}->{'error'}); # Yes, I'm lazy...
  36
  37 # Check if the root directory exists
  38
  39 abort($config->{'errors'}->{'no_root_dir'}) unless(-d $config->{'fileroot'} && not -l $config->{'fileroot'});
  40
  41 # Check if we are able to access the root directory
  42
  43 abort($config->{'errors'}->{'no_root_access'}) unless(-r $config->{'fileroot'} && -x $config->{'fileroot'});
  44
  45 # Read the most important form data
  46
  47 my $cgi = new CGI;
  48
  49 my $command = $cgi->param('command') || 'show';
  50 my $file    = $cgi->param('file')    || '/';
  51 my $curdir  = $cgi->param('curdir')  || '';
  52 my $newfile = $cgi->param('newfile') || '';
  53
  54 # Create physical and virtual path for the new file
  55
  56 my $new_physical = '';
  57 my $new_virtual  = '';
  58
  59 if($newfile ne '' && $newfile !~ /^\s+$/)
  60 {
  61  my $path = $curdir.'/'.$newfile;
  62
  63  # Extract file and directory name...
  64
  65  my $file = file_name($path);
  66  my $dir  = upper_path($path);
  67
  68  # ... check if the directory exists ...
  69
  70  my $temp_path = clean_path($config->{'fileroot'}.'/'.$dir);
  71
  72  unless(-d $temp_path && not -l $temp_path)
  73  {
  74   abort($config->{'errors'}->{'dir_not_exist'},'/');
  75  }
  76
  77  # ... and check if the path is above the root directory
  78
  79  unless(($new_physical,$new_virtual) = check_path($config->{'fileroot'},$dir))
  80  {
  81   abort($config->{'errors'}->{'create_above_root'},'/');
  82  }
  83
  84  # Check if we have enough permissions to create a file
  85  # in this directory
  86
  87  unless(-r $new_physical && -w $new_physical && -x $new_physical)
  88  {
  89   abort($config->{'errors'}->{'dir_no_create'},'/',{DIR => encode_html($new_virtual)});
  90  }
  91
  92  # Create the physical and the virtual path
  93
  94  $new_physical = File::Spec->canonpath($new_physical.'/'.$file);
  95  $new_virtual .= $file;
  96
  97  # Check if accessing this file is forbidden
  98
  99  if(is_forbidden_file($config->{'forbidden'},$new_virtual))
 100  {
 101   abort($config->{'errors'}->{'forbidden_file'},'/');
 102  }
 103 }
 104
 105 # This check has to be performed first or abs_path() will be confused
 106
 107 my $temp_path = clean_path($config->{'fileroot'}.'/'.$file);
 108
 109 if(-e $temp_path || -l $temp_path)
 110 {
 111  if(my ($physical,$virtual) = check_path($config->{'fileroot'},$file))
 112  {
 113   if(is_forbidden_file($config->{'forbidden'},$virtual))
 114   {
 115    abort($config->{'errors'}->{'forbidden_file'},'/');
 116   }
 117   else
 118   {
 119    # Create a hash containing data submitted by the user
 120    # (some other necessary information are also included)
 121
 122    my %data = (physical     => $physical,
 123                virtual      => $virtual,
 124                new_physical => $new_physical,
 125                new_virtual  => $new_virtual,
 126                cgi          => $cgi,
 127                version      => $VERSION,
 128                configfile   => CONFIGFILE);
 129
 130    # Execute the command...
 131
 132    my $output = exec_command($command,\%data,$config);
 133
 134    # ... and show its output
 135
 136    print $$output;
 137   }
 138  }
 139  else
 140  {
 141   abort($config->{'errors'}->{'above_root'},'/');
 142  }
 143 }
 144 else
 145 {
 146  abort($config->{'errors'}->{'not_found'},'/');
 147 }
 148
 149 #
 150 ### End ###