selfforum-cgi/shared/Mail.pm

   1 # Mail.pm
   2
   3 ##############################################
   4 #                                            #
   5 # Autor: n.d.p. nd@o3media.de                #
   6 #                                            #
   7 # Letze Aenderung: n.d.p. / 2001-01-03       #
   8 #                                            #
   9 # ========================================== #
  10 #                                            #
  11 # Funktion:                                  #
  12 #      ganz simples Formatieren und Senden   #
  13 #      einer Mail im text/plain, qp-Format   #
  14 #                                            #
  15 ##############################################
  16
  17 use strict;
  18
  19 package Mail;
  20
  21 use vars qw($mailbox $mailprog @ISA @EXPORT);
  22
  23 # ===================
  24 # Funktionsexport
  25 # ===================
  26
  27 require Exporter;
  28 @ISA = qw(Exporter);
  29 @EXPORT = qw(is_mail_address send_mail);
  30
  31 ########################################
  32 # EXPORT
  33 # sub is_mail_address
  34 #
  35 # Funktion:
  36 #      Ueberpruefen der Syntax einer
  37 #      Email-Adresse
  38 #
  39 # Rueckgabe
  40 #      true/false
  41 ########################################
  42
  43 sub is_mail_address ($) {
  44   return ($_[0] =~ /$mailbox/);
  45 }
  46
  47 ########################################
  48 # EXPORT
  49 # sub send_mail
  50 #
  51 # Funktion:
  52 #      Senden der Nachricht
  53 #      ueber open-print-close
  54 #      $Mail::mailprog enthaelt
  55 #      den vollstaendigen string fuer
  56 #      open, dass heisst, es kann
  57 #      auch ein Dateiname sein.
  58 #
  59 # Rueckgabe:
  60 #      true/false
  61 ########################################
  62
  63 sub send_mail {
  64   my $param=shift;
  65   local *MAIL;
  66
  67   open MAIL,$mailprog or return 0;
  68     print MAIL &as_string ($param);
  69   close MAIL and return 1;
  70
  71   # Hier muss irgendwas schiefgelaufen sein
  72   0;
  73 }
  74
  75 ##########################################
  76 # PRIVAT
  77 # sub as_string
  78 #
  79 # Funktion:
  80 #      Bereitstellung der gesamten Mail
  81 #      als String.
  82 #
  83 # Rueckgabe:
  84 #      String
  85 ##########################################
  86
  87 sub as_string {
  88   my $param=shift;
  89
  90   my $header=&header_as_string ($param);
  91   my $body=&body_as_string ($param);
  92
  93   # Rueckgabe
  94   "$header\n$body\n";
  95 }
  96
  97 ##########################################
  98 # PRIVAT
  99 # sub body_as_string
 100 #
 101 # Funktion:
 102 #      Bereitstellung des Bodys
 103 #      als (qp-codierten) String.
 104 #
 105 # Rueckgabe:
 106 #      String
 107 ##########################################
 108
 109 sub body_as_string {
 110   my $param=shift;
 111
 112   &encode_qp($param->{body});
 113 }
 114
 115 ##########################################
 116 # PRIVAT
 117 # sub header_as_string
 118 #
 119 # Funktion:
 120 #      Bereitstellung des Headers
 121 #      als String.
 122 #
 123 # Rueckgabe:
 124 #      String
 125 ##########################################
 126
 127 sub header_as_string {
 128   my $param=shift;
 129
 130   my $string="Content-Disposition: inline\n";
 131      $string.="MIME-Version: 1.0\n";
 132      $string.="Content-Transfer-Encoding: quoted-printable\n";
 133      $string.="Content-Type: text/plain\n";
 134      $string.="Date: ".&rfc822_date(time)."\n";
 135      $string.="From: ".$param->{'from'}."\n";
 136      $string.=&get_list('To',$param->{'to'});
 137      $string.=&get_list('Cc',$param->{'cc'});
 138      $string.=&get_list('Bcc',$param->{'bcc'});
 139      $string.="Subject: ".encode_qp($param->{'subject'})."\n";
 140
 141   # Rueckgabe
 142   $string;
 143 }
 144
 145 #######################################
 146 # PRIVAT
 147 # sub encode_qp
 148 #
 149 # C&P aus dem Modul MIME::QuotedPrint
 150 # Thanx for that
 151 #######################################
 152
 153 sub encode_qp ($)
 154 {
 155     my $res = shift;
 156     $res =~ s/([^ \t\n!-<>-~])/sprintf("=%02X", ord($1))/eg;  # rule #2,#3
 157     $res =~ s/([ \t]+)$/
 158       join('', map { sprintf("=%02X", ord($_)) }
 159                    split('', $1)
 160       )/egm;                        # rule #3 (encode whitespace at eol)
 161
 162     # rule #5 (lines must be shorter than 76 chars, but we are not allowed
 163     # to break =XX escapes.  This makes things complicated :-( )
 164     my $brokenlines = "";
 165     $brokenlines .= "$1=\n"
 166         while $res =~ s/(.*?^[^\n]{73} (?:
 167                  [^=\n]{2} (?! [^=\n]{0,1} $) # 75 not followed by .?\n
 168                 |[^=\n]    (?! [^=\n]{0,2} $) # 74 not followed by .?.?\n
 169                 |          (?! [^=\n]{0,3} $) # 73 not followed by .?.?.?\n
 170             ))//xsm;
 171
 172     "$brokenlines$res";
 173 }
 174
 175 ##############################################
 176 # PRIVAT
 177 # sub get_list
 178 #
 179 # Funktion:
 180 #      Aufbereitung einer Liste oder eines
 181 #      Strings fuer den Header (To, Cc, Bcc)
 182 #
 183 # Rueckgabe:
 184 #      Ergebnis oder nichts
 185 ##############################################
 186
 187 sub get_list ($$) {
 188   my ($start,$list)=splice @_;
 189
 190   return $start . ': ' . $list . "\n" if (defined $list and not ref $list and length $list);
 191
 192   return $start . ': ' . join (', ',@$list) . "\n" if (ref $list);
 193
 194   '';
 195 }
 196
 197 ##############################################
 198 # PRIVAT
 199 # sub rfc822_date
 200 #
 201 # Funktion:
 202 #      Bereitstellung eines RFC-konformen
 203 #      Datumstrings
 204 #
 205 # Rueckgabe:
 206 #      Datumstring
 207 ##############################################
 208
 209 sub rfc822_date ($) {
 210   my ($sek, $min, $std, $mtag, $mon, $jahr, $wtag) = gmtime (+shift);
 211
 212   sprintf ('%s, %02d %s %04d %02d:%02d:%02d GMT',
 213              (qw(Sun Mon Tue Wed Thu Fri Sat))[$wtag],
 214              $mtag,
 215              (qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec))[$mon],
 216              $jahr+1900, $std, $min, $sek);
 217 }
 218
 219 ##############################################
 220 # Modulinitialisierung
 221 # BEGIN
 222 #
 223 # Funktion:
 224 #      Bereitstellung des Regexps und des
 225 #      Mailprogs
 226 ##############################################
 227
 228 BEGIN {
 229     # Standard-Mailprogramm
 230
 231     # Dieser String wird so, wie er ist, an die open-Anweisung geschickt,
 232     # -t  = tainted(?),der Header (=alles bis zur ersten Leerzeile)
 233     #       wird nach To:, Cc: und evtl. Bcc: abgesucht.
 234     # -oi = damit wird verhindert, dass sendmail, ein Zeile, wo nur ein
 235     #       Punkt drinsteht, als Mailende erkennt( waere Standard ).
 236     # ===================================================================
 237
 238     $mailprog = '|/usr/lib/sendmail -t -oi';
 239
 240     # Thanx to J. Friedl for this regex:
 241
 242     my ($address,$route_addr,$phrase,$addr_spec,$X,$phrase_char,$quoted_str,$comment,$word,$phrase_ctrl,$NonASCII,
 243         $CloseBR,$OpenBR,$esc,$route,$domain,$local_part,$Period,$sub_domain,$domain_lit,$domain_ref,$quoted_pair,
 244         $dtext,$atom,$qtext,$atom_char,$ctrl,$space,$tab,$CloseParen,$ctext,$Cnested,$OpenParen,$CRlist);
 245
 246     $esc        = '\\\\';
 247     $Period      = '\.';
 248     $space      = '\040';
 249     $tab         = '\t';
 250     $OpenBR     = '\[';
 251     $CloseBR     = '\]';
 252     $OpenParen  = '\(';
 253     $CloseParen  = '\)';
 254     $NonASCII   = '\x80-\xff';
 255     $ctrl        = '\000-\037';
 256     $CRlist     = '\n\015';
 257     $qtext = qq/[^$esc$NonASCII$CRlist\"]/;
 258     $dtext = qq/[^$esc$NonASCII$CRlist$OpenBR$CloseBR]/;
 259     $quoted_pair = qq< $esc [^$NonASCII] >;
 260     $ctext   = qq< [^$esc$NonASCII$CRlist()] >;
 261     $Cnested = qq< $OpenParen $ctext* (?: $quoted_pair $ctext* )* $CloseParen >;
 262     $comment = qq< $OpenParen $ctext* (?: (?: $quoted_pair | $Cnested ) $ctext* )* $CloseParen >;
 263     $X = qq< [$space$tab]* (?: $comment [$space$tab]* )* >;
 264     $atom_char   = qq/[^($space)<>\@,;:\".$esc$OpenBR$CloseBR$ctrl$NonASCII]/;
 265     $atom = qq< $atom_char+ (?!$atom_char) >;
 266     $quoted_str = qq< \" $qtext * (?: $quoted_pair $qtext * )* \" >;
 267     $word = qq< (?: $atom | $quoted_str ) >;
 268     $domain_ref  = $atom;
 269     $domain_lit  = qq< $OpenBR (?: $dtext | $quoted_pair )* $CloseBR >;
 270     $sub_domain  = qq< (?: $domain_ref | $domain_lit ) $X >;
 271     $domain = qq< $sub_domain (?: $Period $X $sub_domain )* >;
 272     $route = qq< \@ $X $domain (?: , $X \@ $X $domain )* : $X >;
 273     $local_part = qq< $word $X (?: $Period $X $word $X )* >;
 274     $addr_spec  = qq< $local_part \@ $X $domain >;
 275     $route_addr = qq[ < $X (?: $route )? $addr_spec > ];
 276     $phrase_ctrl = '\000-\010\012-\037';
 277     $phrase_char = qq/[^()<>\@,;:\".$esc$OpenBR$CloseBR$NonASCII$phrase_ctrl]/;
 278     $phrase = qq< $word $phrase_char * (?: (?: $comment | $quoted_str ) $phrase_char * )* >;
 279     $mailbox = qq< $X (?: $addr_spec | $phrase  $route_addr ) >;
 280     $mailbox = qr ~^$mailbox$~x;
 281 }
 282
 283 # making 'require' happy
 284 1;
 285
 286 #####################
 287 # end of Mail
 288 #####################