modules/Template.pm

   1 package Template;
   2
   3 #
   4 # Template (Version 1.5)
   5 #
   6 # Klasse zum Parsen von Templates
   7 #
   8 # Autor:            Patrick Canterino <patrick@patshaping.de>
   9 # Letzte Aenderung: 4.5.2005
  10 #
  11
  12 use strict;
  13
  14 use Carp qw(croak);
  15
  16 # new()
  17 #
  18 # Konstruktor
  19 #
  20 # Parameter: -keine-
  21 #
  22 # Rueckgabe: Template-Objekt
  23
  24 sub new
  25 {
  26  my $class = shift;
  27  my $self  = {file => '', template => ''};
  28  return bless($self,$class);
  29 }
  30
  31 # get_template()
  32 #
  33 # Kompletten Vorlagentext zurueckgeben
  34 #
  35 # Parameter: -keine-
  36 #
  37 # Rueckgabe: Kompletter Vorlagentext (String)
  38
  39 sub get_template
  40 {
  41  return shift->{'template'};
  42 }
  43
  44 # set_template()
  45 #
  46 # Kompletten Vorlagentext aendern
  47 #
  48 # Parameter: Vorlagentext
  49 #
  50 # Rueckgabe: -nichts- (Template-Objekt wird modifiziert)
  51
  52 sub set_template($)
  53 {
  54  # Geht nur so...
  55
  56  my ($self,$template) = @_;
  57  $self->{'template'}  = $template;
  58 }
  59
  60 # add_text()
  61 #
  62 # Vorlagentext ans Template-Objekt anhaengen
  63 #
  64 # Parameter: Vorlagentext
  65 #
  66 # Rueckgabe: -nichts- (Template-Objekt wird modifiziert)
  67
  68 sub add_text($)
  69 {
  70  my ($self,$text) = @_;
  71  $self->set_template($self->get_template.$text);
  72 }
  73
  74 # read_file()
  75 #
  76 # Einlesen einer Vorlagendatei und {INCLUDE}-Anweisungen ggf. verarbeiten
  77 # (Text wird an bereits vorhandenen Text angehaengt)
  78 #
  79 # Parameter: 1. Datei zum Einlesen
  80 #            2. Status-Code (Boolean):
  81 #               true  => {INCLUDE}-Anweisungen nicht verarbeiten
  82 #               false => {INCLUDE}-Anweisungen verarbeiten (Standard)
  83 #
  84 # Rueckgabe: -nichts- (Template-Objekt wird modifiziert)
  85
  86 sub read_file($;$)
  87 {
  88  my ($self,$file,$not_include) = @_;
  89  local *FILE;
  90
  91  $self->{'file'} = $file;
  92
  93  open(FILE,'<'.$file) or croak "Open $file: $!";
  94  read(FILE, my $content, -s $file);
  95  close(FILE) or croak "Closing $file: $!";
  96
  97  $self->add_text($content);
  98  $self->parse_includes unless($not_include);
  99 }
 100
 101 # fillin()
 102 #
 103 # Variablen durch Text ersetzen
 104 #
 105 # Parameter: 1. Variable zum Ersetzen
 106 #            2. Text, durch den die Variable ersetzt werden soll
 107 #
 108 # Rueckgabe: -nichts- (Template-Objekt wird modifiziert)
 109
 110 sub fillin($$)
 111 {
 112  my ($self,$var,$text) = @_;
 113
 114  $var  = quotemeta($var);
 115  $text = '' unless defined $text; # Um Fehler zu vermeiden
 116
 117  my $template = $self->get_template;
 118  $template    =~ s/\{$var\}/$text/g;
 119
 120  $self->set_template($template);
 121 }
 122
 123 # fillin_array()
 124 #
 125 # Variable durch Array ersetzen
 126 #
 127 # Parameter: 1. Variable zum Ersetzen
 128 #            2. Array-Referenz, durch die die Variable ersetzt werden soll
 129 #            3. Zeichenkette, mit der das Array verbunden werden soll
 130 #               (Standard: '')
 131 #
 132 # Rueckgabe: -nichts- (Template-Objekt wird modifiziert)
 133
 134 sub fillin_array($$;$)
 135 {
 136  my ($self,$var,$array,$glue) = @_;
 137  $glue = '' unless defined $glue;
 138
 139  $self->fillin($var,join($glue,@$array));
 140 }
 141
 142 # to_file()
 143 #
 144 # Template in Datei schreiben
 145 #
 146 # Parameter: Datei-Handle
 147 #
 148 # Rueckgabe: Status-Code (Boolean)
 149
 150 sub to_file($)
 151 {
 152  my ($self,$handle) = @_;
 153  return print $handle $self->get_template;
 154 }
 155
 156 # parse_if_block()
 157 #
 158 # IF-Bloecke verarbeiten
 159 #
 160 # Parameter: 1. Name des IF-Blocks (das, was nach dem IF steht)
 161 #            2. Status-Code (true  => Inhalt anzeigen
 162 #                            false => Inhalt nicht anzeigen
 163 #            3. true  => Verneinten Block nicht parsen
 164 #               false => Verneinten Block parsen (Standard)
 165 #
 166 # Rueckgabe: -nichts- (Template-Objekt wird modifiziert)
 167
 168 sub parse_if_block($$;$)
 169 {
 170  my ($self,$name,$state,$no_negate) = @_;
 171  my $template                       = $self->get_template;
 172
 173  my $count = 0;
 174
 175  while(index($template,'{IF '.$name.'}') >= 0)
 176  {
 177   # Das alles hier ist nicht wirklich elegant geloest...
 178   # ... aber solange es funktioniert... ;-)
 179
 180   $count++;
 181
 182   my $start    = index($template,'{IF '.$name.'}');
 183   my $tpl_tmp  = substr($template,$start);
 184   my @splitted = split(/\{ENDIF\}/,$tpl_tmp);
 185
 186   # Wenn sich am Ende der Zeichenkette {ENDIF} befinden, werden diese
 187   # von split() ignoriert, was zu einem Verschachtelungsfehler fuehrt
 188   # Die fehlenden leeren Zeichenketten muessen von Hand eingefuegt werden
 189
 190   my $x = 1;
 191
 192   while(substr($tpl_tmp,-7*$x,7) eq '{ENDIF}')
 193   {
 194    push(@splitted,'');
 195    $x++;
 196   }
 197
 198   my $block = ''; # Kompletter bedingter Block
 199   my $ifs   = 0;  # IF-Zaehler (wird fuer jedes IF erhoeht und fuer jedes ENDIF erniedrigt)
 200
 201   # {IF}
 202
 203   for(my $x=0;$x<@splitted;$x++)
 204   {
 205    croak 'Nesting error found while parsing IF block "'.$name.'" nr. '.$count.' in template file "'.$self->{'file'}.'"' if($x == $#splitted);
 206
 207    $ifs += substr_count($splitted[$x],'{IF '); # Zum Zaehler jedes Vorkommen von IF hinzuzaehlen
 208    $ifs--;                                     # Zaehler um 1 erniedrigen
 209    $block .= $splitted[$x].'{ENDIF}';          # Daten zum Block hinzufuegen
 210
 211    if($ifs == 0)
 212    {
 213     # Zaehler wieder 0, also haben wir das Ende des IF-Blocks gefunden :-))
 214
 215     last;
 216    }
 217   }
 218
 219   my $if_block = substr($block,length($name)+5,-7); # Alles zwischen {IF} und {ENDIF}
 220
 221   # {ELSE}
 222
 223   my $else_block = ''; # Alles ab {ELSE}
 224      $ifs        = 0;  # IF-Zaehler
 225
 226   @splitted = split(/\{ELSE\}/,$if_block);
 227
 228   for(my $x=0;$x<@splitted;$x++)
 229   {
 230    $ifs += substr_count($splitted[$x],'{IF ');    # Zum Zaehler jedes Vorkommen von IF hinzuzaehlen
 231    $ifs -= substr_count($splitted[$x],'{ENDIF}'); # Vom Zaehler jedes Vorkommen von ENDIF abziehen
 232
 233    if($ifs == 0)
 234    {
 235     # Zaehler 0, also haben wir das Ende des IF-Abschnitts gefunden
 236
 237     # Aus dem Rest den ELSE-Block zusammenbauen
 238
 239     for(my $y=$x+1;$y<@splitted;$y++)
 240     {
 241      $else_block .= '{ELSE}'.$splitted[$y];
 242     }
 243
 244     if($else_block)
 245     {
 246      $if_block   = substr($if_block,0,length($if_block)-length($else_block));
 247      $else_block = (length($else_block) > 6) ? substr($else_block,6) : '';    # Ansonsten gibt es Fehler
 248     }
 249
 250     last;
 251    }
 252   }
 253
 254   my $replacement = ($state) ? $if_block : $else_block;
 255
 256   my $qmblock = quotemeta($block);
 257
 258   $template =~ s/$qmblock/$replacement/;
 259  }
 260
 261  $self->set_template($template);
 262
 263  # Evtl. verneinte Form parsen
 264
 265  unless($no_negate)
 266  {
 267   $self->parse_if_block('!'.$name,not($state),1);
 268  }
 269 }
 270
 271 # parse_condtag()
 272 #
 273 # Bedingungstags in einem Vorlagentext verarbeiten
 274 #
 275 # Parameter: 1. Tagname
 276 #            2. Status-Code (true  => Tag-Inhalt anzeigen
 277 #                            false => Tag-Inhalt nicht anzeigen
 278 #
 279 # Rueckgabe: -nichts- (Template-Objekt wird modifiziert)
 280
 281 sub parse_condtag($$)
 282 {
 283  my ($self,$condtag,$state) = @_;
 284
 285  my $template = $self->get_template;
 286
 287  while(index($template,'<'.$condtag.'>') >= 0)
 288  {
 289   my $start = index($template,'<'.$condtag.'>');                                # Beginn des Blocks
 290   my $end   = index($template,'</'.$condtag.'>')+length($condtag)+3;            # Ende des Blocks
 291
 292   my $extract = substr($template,$start,$end-$start);                           # Kompletten Bedingungsblock extrahieren...
 293
 294   my $replacement = ($state) ? substr($extract,length($condtag)+2,0-length($condtag)-3) : '';
 295
 296   $extract = quotemeta($extract);
 297
 298   $template =~ s/$extract/$replacement/g;                                       # Block durch neue Daten ersetzen
 299  }
 300  $self->set_template($template);
 301 }
 302
 303 # parse_includes()
 304 #
 305 # {INCLUDE}-Anweisungen verarbeiten
 306 #
 307 # Parameter: -nichts-
 308 #
 309 # Rueckgabe: -nichts- (Template-Objekt wird modifiziert)
 310
 311 sub parse_includes
 312 {
 313  my $self     = shift;
 314  my $template = $self->get_template;
 315
 316  while($template =~ /(\{INCLUDE (\S+?)\})/g)
 317  {
 318   my ($directive,$file) = ($1,$2);
 319   my $qm_directive      = quotemeta($directive);
 320
 321   if(-f $file)
 322   {
 323    my $inc = new Template;
 324    $inc->read_file($file);
 325
 326    $template =~ s/$qm_directive/$inc->get_template/eg;
 327   }
 328  }
 329
 330  $self->set_template($template);
 331 }
 332
 333 # ==================
 334 #  Private Funktion
 335 # ==================
 336
 337 # substr_count()
 338 #
 339 # Zaehlt, wie oft ein String in einem String vorkommt
 340 # (Emulation der PHP-Funktion substr_count())
 341 #
 342 # Parameter: 1. Zu durchsuchender String
 343 #            2. Zu suchender String
 344 #
 345 # Rueckgabe: Anzahl der Vorkommnisse (Integer)
 346
 347 sub substr_count($$)
 348 {
 349  my ($haystack,$needle) = @_;
 350  my $qmneedle = quotemeta($needle);
 351
 352  my $count = 0;
 353
 354  $count++ while($haystack =~ /$qmneedle/g);
 355
 356  return $count;
 357 }
 358
 359 # ==================
 360 #  Alias-Funktionen
 361 # ==================
 362
 363 *addtext   = \&add_text;
 364 *as_string = \&get_template;
 365 *condtag   = \&parse_condtag;
 366 *readin    = \&read_file;
 367
 368 # it's true, baby ;-)
 369
 370 1;
 371
 372 #
 373 ### Ende ###